{ pkgs ? import <nixpkgs> {} }: let
  package = {
    rustPlatform,
    nix-gitignore,
    pkg-config,
    openssl,
    glib,
    gdk-pixbuf,
    graphene,
    cairo,
    pango,
    gtk4,
    libsoup_3,
    libadwaita,
    webkitgtk_6_0,
    libseccomp,
    wrapGAppsHook4,
    glib-networking,
  }: rustPlatform.buildRustPackage {
    pname = "paket";
    version = "unstable-2024-09-28";

    src = nix-gitignore.gitignoreSource [] ./.;

    cargoLock = {
      lockFile = ./Cargo.lock;
      outputHashes = {
        "relm4-0.9.0" = "sha256-iFxi2ZWdzWtui85IOfMIfyuPDbQO69u5VLk0a9ebatM=";
        "relm4-icons-0.9.0" = "sha256-UUo1wIvJL2MryUFICnmVq6LoPuNaZ9nKcNGCCF8cx+k=";
      };
    };

    nativeBuildInputs = [
      pkg-config
      graphene
      cairo
      wrapGAppsHook4
    ];

    buildInputs = [
      # Building
      openssl
      glib
      gdk-pixbuf
      pango
      gtk4
      libsoup_3
      libadwaita
      webkitgtk_6_0 # for JSC

      # Linking
      libseccomp

      # Runtime
      glib-networking
    ];

    meta = {
      mainProgram = "packet";
    };
  };
in pkgs.callPackage package { }